namespace Dino.Entities {

public class Settings : Object {

    public signal void account_color_changed(Account account, string color);

    private Database db;

    public Settings.from_db(Database db) {
        this.db = db;

        send_typing_ = col_to_bool_or_default("send_typing", true);
        send_marker_ = col_to_bool_or_default("send_marker", true);
        share_time_ = col_to_bool_or_default("share_time", true);
        notifications_ = col_to_bool_or_default("notifications", true);
        convert_utf8_smileys_ = col_to_bool_or_default("convert_utf8_smileys", true);
        check_spelling = col_to_bool_or_default("check_spelling", true);
    }

    private bool col_to_bool_or_default(string key, bool def) {
        string? val = db.settings.select({db.settings.value}).with(db.settings.key, "=", key)[db.settings.value];
        return val != null ? bool.parse(val) : def;
    }

    private bool send_typing_;
    public bool send_typing {
        get { return send_typing_; }
        set {
            db.settings.upsert()
                    .value(db.settings.key, "send_typing", true)
                    .value(db.settings.value, value.to_string())
                    .perform();
            send_typing_ = value;
        }
    }

    private bool send_marker_;
    public bool send_marker {
        get { return send_marker_; }
        set {
            db.settings.upsert()
                    .value(db.settings.key, "send_marker", true)
                    .value(db.settings.value, value.to_string())
                    .perform();
            send_marker_ = value;
        }
    }

    private bool share_time_;
    public bool share_time {
        get { return share_time_; }
        set {
            db.settings.upsert()
                    .value(db.settings.key, "share_time", true)
                    .value(db.settings.value, value.to_string())
                    .perform();
            share_time_ = value;
        }
    }

    private bool notifications_;
    public bool notifications {
        get { return notifications_; }
        set {
            db.settings.upsert()
                    .value(db.settings.key, "notifications", true)
                    .value(db.settings.value, value.to_string())
                    .perform();
            notifications_ = value;
        }
    }

    private bool convert_utf8_smileys_;
    public bool convert_utf8_smileys {
        get { return convert_utf8_smileys_; }
        set {
            db.settings.upsert()
                    .value(db.settings.key, "convert_utf8_smileys", true)
                    .value(db.settings.value, value.to_string())
                    .perform();
            convert_utf8_smileys_ = value;
        }
    }

    // There is currently no spell checking for GTK4, thus there is currently no UI for this setting.
    private bool check_spelling_;
    public bool check_spelling {
        get { return check_spelling_; }
        set {
            db.settings.upsert()
                .value(db.settings.key, "check_spelling", true)
                .value(db.settings.value, value.to_string())
                .perform();
            check_spelling_ = value;
        }
    }

    public Encryption get_default_encryption(Account account) {
        string? setting = db.account_settings.get_value(account.id, "default-encryption");
        if (setting != null) {
            return (Encryption) int.parse(setting);
        }
        return Encryption.OMEMO;
    }

    public void set_default_encryption(Account account, Encryption encryption) {
        db.account_settings.upsert()
                .value(db.account_settings.key, "default-encryption", true)
                .value(db.account_settings.account_id, account.id, true)
                .value(db.account_settings.value, ((int)encryption).to_string())
                .perform();


    }

    public string get_account_color(Account account) {
        string? setting = db.account_settings.get_value(account.id, "conversation-list-color");
        if (setting != null && setting.length > 0) {
            return setting;
        }

        uint8[] rgb = Xmpp.Xep.ConsistentColor.string_to_rgb(account.bare_jid.to_string());
        return "#%02x%02x%02x".printf(rgb[0], rgb[1], rgb[2]).up();
    }

    public void set_account_color(Account account, string color) {
        if (color == get_account_color(account)) return;

        db.account_settings.upsert()
                .value(db.account_settings.key, "conversation-list-color", true)
                .value(db.account_settings.account_id, account.id, true)
                .value(db.account_settings.value, color)
                .perform();
        account_color_changed(account, color);
    }
}

}